REM Start of BASIC! Program

WAKELOCK 4

nx=30
ac=INT(RND()*2) %alternate colors

GR.OPEN 255,0,0,0,0,1
GR.SCREEN sx,sy

ny=INT(nx/sx*sy)

rx=sx/nx
ry=sy/ny

GR.BITMAP.CREATE bmp1,sx*1.2,sx*1.2
GR.BITMAP.CREATE bmp2,sx*1.2,sx*1.2

nx1=INT(nx*1.2)

GR.BITMAP.DRAWINTO.START bmp1
GR.COLOR 255,255,128,0,1
FOR i=1 TO nx1
 FOR j=1 TO nx1
  x=i*rx-rx/2
  y=j*ry-ry/2
  l=HYPOT(sx/2-x+sx*0.1,sx/2-y+sx*0.1)/(sx/2)*255
  IF l<255 THEN
   IF ac THEN
    IF j/2=INT(j/2) THEN
     IF i/2=INT(i/2) THEN
      GR.COLOR 255,255-l,0,0,1
     ELSE
      GR.COLOR 255,0,0,255-l,1
     ENDIF
    ELSE
     IF i/2=INT(i/2) THEN
      GR.COLOR 255,0,0,255-l,1
     ELSE
      GR.COLOR 255,255-l,0,0,1
     ENDIF
    ENDIF
   ELSE
    GR.COLOR 255,255-l,255-l,255-l,1
   ENDIF
   GR.CIRCLE vd,x,y,rx/3
  ENDIF
 NEXT j
NEXT i
GR.BITMAP.DRAWINTO.END

GR.BITMAP.DRAWINTO.START bmp2
GR.SET.ANTIALIAS 0
GR.COLOR 255,0,0,0,0
GR.CIRCLE vd,sx/2+sx*0.1,sx/2+sx*0.1,sx/2*1.2
FOR i=1 TO nx
 FOR j=1 TO nx
  x=i*rx-rx/2
  y=j*rx-rx/2
  IF HYPOT(x-sx/2,y-sx/2)<sx/2 THEN
   GR.CIRCLE vd,x+sx*0.1,y+sx*0.1,rx/3
  ENDIF
 NEXT j
NEXT i
GR.SET.ANTIALIAS 1
GR.BITMAP.DRAWINTO.END

GR.COLOR 255,0,0,0,1
GR.BITMAP.FILL bmp2,sx/2+sx*0.1,1

GR.BITMAP.DRAW gob1,bmp1,0,0
GR.ROTATE.START 0.5,sx/2,sy/2,rot
GR.BITMAP.DRAW gob2,bmp2,-sx*0.1,(sy-sx)/2-sx*0.1
GR.ROTATE.END

POPUP "touch screen to pause",,sy/5*2,2

a=0
DO
 GR.TOUCH tt,tx,ty
 IF tt THEN
  DO
   GR.TOUCH tt,tx,ty
  UNTIL !tt
  POPUP "touch screen to go on",,sy/5*2,2
  DO
   GR.TOUCH tt,tx,ty
   PAUSE 20
  UNTIL tt
  DO
   GR.TOUCH tt,tx,ty
  UNTIL !tt
  POPUP "touch screen to pause",,sy/5*2,2
 ENDIF
 a+=0.1
 b+=PI()/133
 c+=PI()/187
 GR.MODIFY rot,"angle",a
 GR.MODIFY gob1,"x", COS(b)*rx-sx*0.1,"y",SIN(c)*ry+(sy-sx)/2-sx*0.1
 GR.RENDER
UNTIL 0