0 CLS:W%=SCREENWIDTH(0):H%=SCREENHEIGHT(0):HS%=STRINGHEIGHT(" "):CHISLO%=H%/HS%-1
1 X%=0:XX%=0:AA%=0:AAA%=0:II%=0:SCHETCHIK%=0:PATHS$="file://":FLAG%=0:DIM DLINA%(30)
2 TEL$=PROPERTY$("microedition.platform")
3 IF TEL$="BENQ-EF81" THEN SLEEP1%=100:SLEEP2%=0:GOTO 9
4 IF TEL$="SonyEricssonZ530i/R6AC001" THEN SLEEP1%=150:SLEEP2%=200:GOTO 9
5 IF TEL$="CX70" OR TEL$="C72" OR TEL$="C65" OR TEL$="CX65" OR TEL$="M65" OR TEL$="S65" OR TEL$="CX75" OR TEL$="M75" THEN SLEEP1%=80:SLEEP2%=0:GOTO 9
8 SLEEP1%=160:SLEEP2%=200
9 OST%=MOD(H%,HS%)
10 IF OST%<>0 THEN OST%=OST%/2
20 Y%=OST%:YY%=OST%
30 DLINA%(SCHETCHIK%)=LEN(PATHS$)
40 A%=1
50 C$=PATHS$+"*"
60 D$=""
70 D$=READDIR$(C$)
80 IF D$<>"" THEN A%=A%+1:D$=READDIR$(""):GOTO 80
90 DIM PAPKA$(A%)
100 PAPKA$(0)=" .  ."
110 A%=1
120 D$=READDIR$(C$)
130 IF D$<>"" THEN PAPKA$(A%)=D$:A%=A%+1:D$=READDIR$(""):GOTO 130
140 IF (A%-1)<CHISLO% THEN AA%=A%-1:GOTO 160
150 AA%=CHISLO%
160 SETCOLOR 255,255,255
170 FILLRECT 0,0,W%,H%
180 SETCOLOR 0,0,0
190 FOR I%=0 TO AA%
200 DRAWSTRING PAPKA$(AAA%),X%,Y%
210 Y%=Y%+HS%:AAA%=AAA%+1
220 NEXT I%
230 GELGRAB "SCREEN",0,0,W%,H%
240 SETCOLOR 0,0,0
250 FILLRECT X%,YY%,W%,HS%
260 SETCOLOR 255,255,255
270 DRAWSTRING PAPKA$(XX%),X%,YY%
300 IF FLAG%=0 THEN GOTO 330
310 SLEEP SLEEP1%
320 FLAG%=0
330 IF GAMEA(0) THEN END
340 IF DOWN(0) THEN FLAG%=1:GOTO 500
350 IF UP(0) THEN FLAG%=1:GOTO 600
360 IF FIRE(0) THEN FLAG%=1:GOTO 400
370 SLEEP SLEEP1%
380 GOTO 300
400 IF XX%=0 AND SCHETCHIK%=0 THEN Y%=OST%:AAA%=0:II%=0:GOTO 300
410 IF XX%=0 THEN SCHETCHIK%=SCHETCHIK%-1:PATHS$=LEFT$(PATHS$,DLINA%(SCHETCHIK%)):Y%=OST%:AAA%=0:II%=0:GOSUB 790:GOTO 40
420 IF RIGHT$(PAPKA$(XX%),1)<>"/" THEN GOTO 700
430 DLINA%(SCHETCHIK%)=LEN(PATHS$)
440 SCHETCHIK%=SCHETCHIK%+1
450 IF SCHETCHIK%=1 THEN PATHS$="file:///"
460 PATHS$=PATHS$+PAPKA$(XX%):XX%=0:YY%=OST%:Y%=OST%:AAA%=0:II%=0
470 SLEEP SLEEP2%
480 GOTO 40
500 IF XX%=(I%+II%-1) AND XX%<(A%-1) AND (A%-1)>CHISLO% THEN II%=II%+1:AAA%=II%:XX%=XX%+1:Y%=OST%:GOTO 160
510 YY%=YY%+HS%
520 XX%=XX%+1
530 IF XX%>(A%-1) AND (A%-1)>CHISLO% THEN II%=0:AAA%=0:XX%=0:YY%=OST%:Y%=OST%:GOTO 160
540 IF XX%>(A%-1) THEN XX%=0:YY%=OST%
550 DRAWGEL "SCREEN",0,0
560 GOTO 240
600 IF XX%=0 AND (A%-1)<=CHISLO% THEN XX%=A%-1:YY%=(A%-1)*HS%+OST%:DRAWGEL "SCREEN",0,0:GOTO 240
610 IF XX%=0 THEN II%=A%-1-CHISLO%:AAA%=II%:XX%=A%-1:YY%=CHISLO%*HS%+OST%:Y%=OST%:GOTO 160
620 IF XX%=II% AND XX%>0 AND (A%-1)>CHISLO% THEN II%=II%-1:AAA%=II%:XX%=XX%-1:Y%=OST%:GOTO 160
630 YY%=YY%-HS%
640 XX%=XX%-1
650 DRAWGEL "SCREEN",0,0
660 GOTO 240
700 PATH$=PATHS$+PAPKA$(XX%)
710 CLS
720 PRINT "ZHDJOM!!!"
730 GOTO 800
790 SLEEP SLEEP2%
795 RETURN
800 DIM SUMB%(256)
810 FOR NU%=0 TO 255
820 MM$=CHR$(NU%)
830 SUMB%(NU%)=STRINGWIDTH(MM$)
840 NEXT NU%
850 DIM STRING$(65535)
860 ST$=""
870 OPEN #0,PATH$,"INPUT"
880 TRAP 1000
890 LENG%=0
900 FOR NU%=0 TO 100000
920 GET #0,SU%
925 IF SU%<0 THEN SU%=SU%+256
930 MM$=CHR$(SU%)
960 IF (LENG%+SUMB%(SU%))<W% THEN LENG%=LENG%+SUMB%(SU%):ST$=ST$+MM$:GOTO 920
970 STRING$(NU%)=ST$
980 ST$=MM$:LENG%=SUMB%(SU%)
990 NEXT NU%
1000 STRING$(NU%)=ST$
1010 CLOSE #0
1020 KOL%=NU%
1030 AAA%=0:Y%=OST%:II%=0
1040 IF KOL%<CHISLO% THEN AA%=KOL%:GOTO 1060
1050 AA%=CHISLO%
1060 SETCOLOR 255,255,255
1070 FILLRECT 0,0,W%,H%
1080 SETCOLOR 0,0,0
1090 FOR I%=0 TO AA%
1100 DRAWSTRING STRING$(AAA%),X%,Y%
1110 Y%=Y%+HS%:AAA%=AAA%+1
1120 NEXT I%
1300 IF FLAG%=0 THEN GOTO 1330
1310 SLEEP SLEEP1%
1320 FLAG%=0
1330 IF GAMEA(0) THEN END
1340 IF DOWN(0) THEN FLAG%=1:GOTO 1500
1350 IF UP(0) THEN FLAG%=1:GOTO 1600
1360 IF LEFT(0) THEN FLAG%=1:GOTO 1700
1370 IF RIGHT(0) THEN FLAG%=1:GOTO 1800
1380 IF FIRE(0) THEN GOTO 0
1390 SLEEP SLEEP1%
1395 GOTO 1300
1500 IF AAA%<=KOL% AND KOL%>CHISLO% THEN II%=II%+1:AAA%=II%:Y%=OST%:GOTO 1060
1560 GOTO 1300
1600 IF II%>0 AND KOL%>CHISLO% THEN II%=II%-1:AAA%=II%:Y%=OST%:GOTO 1060
1660 GOTO 1300
1700 IF (II%-CHISLO%-1)>=0 AND KOL%>CHISLO% THEN II%=II%-CHISLO%-1:AAA%=II%:Y%=OST%:GOTO 1060
1710 IF (II%-CHISLO%-1)<0 AND KOL%>CHISLO% THEN II%=0:AAA%=II%:Y%=OST%:GOTO 1060
1760 GOTO 1300
1800 IF ((CHISLO%*2+II%)>=(KOL%-1)) AND KOL%>CHISLO% THEN II%=KOL%-CHISLO%:AAA%=II%:Y%=OST%:GOTO 1060
1810 IF (AAA%<(KOL%-1)) AND ((CHISLO%*2+II%)<(KOL%-1)) AND KOL%>CHISLO% THEN II%=II%+CHISLO%+1:AAA%=II%:Y%=OST%:GOTO 1060
1860 GOTO 1300